Can't install grafana together with dwerder/graphite

[echocat]

Can't install grafana together with dwerder/graphite

[dwerder]

Hi @confiq ,

thats a little bit tricky at the moment. Because the graphite module has a built-in apache install routin. You have to disable it and use the puppetlabs/apache module.

Example:

  include '::apache'

  apache::vhost { graphite.my.domain:
    port    => '80',
    docroot => '/opt/graphite/webapp',
    wsgi_application_group      => '%{GLOBAL}',
    wsgi_daemon_process         => 'graphite',
    wsgi_daemon_process_options => {
      processes          => '5',
      threads            => '5',
      display-name       => '%{GROUP}',
      inactivity-timeout => '120',
    },
    wsgi_import_script          => '/opt/graphite/conf/graphite.wsgi',
    wsgi_import_script_options  => {
      process-group     => 'graphite',
      application-group => '%{GLOBAL}'
    },
    wsgi_process_group          => 'graphite',
    wsgi_script_aliases         => {
      '/' => '/opt/graphite/conf/graphite.wsgi'
    },
    headers => [
        'set Access-Control-Allow-Origin "*"',
        'set Access-Control-Allow-Methods "GET, OPTIONS, POST"',
        'set Access-Control-Allow-Headers "origin, authorization, accept"',
     ],
    directories => [{
      path => '/media/',
      order => 'deny,allow',
      allow => 'from all'}
    ]
  }->
 class { 'graphite':
   gr_web_server => 'none'
 }

  apache::vhost { 'grafana.my.domain':
    servername      => 'grafana.my.domain',
    port            => 80,
    docroot         => '/opt/grafana',
    error_log_file  => 'grafana_error.log',
    access_log_file => 'grafana_access.log',
    directories     => [
      {
        path            => '/opt/grafana',
        options         => [ 'None' ],
        allow           => 'from All',
        allow_override  => [ 'None' ],
        order           => 'Allow,Deny',
      }
    ]
  }->
  class {'grafana':
    graphite_host      => 'graphite.my.domain',
    elasticsearch_host => 'elasticsearach.my.domain',
    elasticsearch_port => 9200,
  }

I hope that fixes you problem.

[confiq]

Yes, after little research i've understand that I should use class { 'graphite': gr_web_server => 'none'} and have my own vhost.

Thanks @dwerder it helped!

[dwerder]

The next major version 6 will use the puppetlabs/apache module if you use gr_web_server => 'apache' and the default will become 'none'. So that you can provide your own webserver config.

Regards

[confiq]

That sounds ideal.
My suggestion is to write in docs about this case
Thanks again @dwerder :)

EDIT: fix