anifyuli/my-nixos

NixOS configurations

• 👋🏻 Hi, I’m Moh. Anif Yuliansyah
• 👀 I’m interested in Kotlin, Flutter, Android, Linux, and OSS
• 🌱 I’m currently learning Kotlin & Flutter
• 💞️ I’m looking to collaborate on Open Source Mini Project
• 📫 You can contact me with email, Facebook, Twitter, Instagram, and Telegram
• 🙇🏻‍♀️ Nice to meet you everyone

my-nixos's Issues

Flakes full feature

Can you adding flakes feature in your configurations?, maybe like this

# file flake.nix
{
  description = "My Configuration";

  # url, nix channel / repo
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11"; # stable channel
    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable"; # unstable channel
    nixos-hardware.url = "github:NixOS/nixos-hardware";
    home-manager.url = "github:nix-community/home-manager/release-23.11"; # for nixos-23.11
  };

  outputs = { self, nixpkgs, nixos-hardware, home-manager, nixpkgs-unstable, ... } @ inputs: let
    inherit (self) outputs; # to export the output variable
    system = "x86_64-linux"; # your system
    genericModules = [
      ./configuration.nix
      {
        # Fix for nixpkgs without flakes
        nix.registry.nixos.flake = inputs.self;
        environment.etc."nix/inputs/nixpkgs".source = nixpkgs.outPath;
        nix.nixPath = [ "nixpkgs=${nixpkgs.outPath}" ];
      }
      # Home manager
      home-manager.nixosModules.home-manager
      {
        nix.registry.nixos.flake = inputs.self;
        home-manager.useGlobalPkgs = true;
        home-manager.useUserPackages = true;
        imports = [
          ./home-manager/home-manager.nix # your home-manager config
        ];
      }
      # closure for adding overlays
      (_: {
        nixpkgs.overlays = [
          overlay-unstable
        ];
      })
    ];
    # list overlays 
    # unstable overlay
    overlay-unstable = _final: _prev: {
      # it will be access in pkgs.unstable
      unstable = import nixpkgs-unstable {
        inherit system;
        config.allowUnfree = true;
      };
    };
  in
  {
    nixosConfiguration = {
      # Your Computer name (hostname)
      "ThinkPad-X280" = nixpkgs.lib.nixosSystem {
        inherit system;
        specialArgs = {
          inherit inputs outputs; # so you can access inputs outputs in your configuration.nix, etc
        };
        modules = genericModules ++ [
          nixos-hardware.nixosModules.lenovo-thinkpad-x280
        ];
      };
    };
  };
}

I forgot to adding android package. (you can do it yourself 👀)
this my configuration https://github.com/fmway/NixOs