Add PHPUnit assertion => FBExpect migration

[hhvm]

Add PHPUnit assertion => FBExpect migration

[fredemmott]

Here's the basics of just assertEquals - doesn't handle whitespace, comments, generating nice code etc, but gets the semantics right:

<?hh // strict
/*
 *  Copyright (c) 2017-present, Facebook, Inc.
 *  All rights reserved.
 *
 *  This source code is licensed under the MIT license found in the
 *  LICENSE file in the root directory of this source tree.
 *
 */

namespace Facebook\HHAST\Linters;

use type Facebook\HHAST\{
  EditableNode,
  EditableList,
  FunctionCallExpression,
  BinaryExpression,
  MemberSelectionExpression,
  LeftParenToken,
  RightParenToken,
  NameToken,
  EqualToken,
  DelimitedComment,
  ListItem,
  CommaToken,
  WhiteSpace,
};
use function Facebook\HHAST\Missing;
use namespace Facebook\TypeAssert;
use namespace HH\Lib\{C, Str, Vec};

final class NoAssertEqualsLinter
  extends AutoFixingASTLinter<FunctionCallExpression> {

  <<__Override>>
  protected static function getTargetType(): classname<FunctionCallExpression> {
    return FunctionCallExpression::class;
  }

  <<__Override>>
  public function getLintErrorForNode(
    FunctionCallExpression $node,
    vec<EditableNode> $parents,
  ): ?FixableASTLintError<FunctionCallExpression> {
    $rec = $node->getReceiver();
    if (!$rec instanceof MemberSelectionExpression) {
      return null;
    }
    $method = $rec->getName()->getCode();
    if ($method !== 'assertEquals') {
      return null;
    }

    return new FixableASTLintError($this, "use fbexpect", $node);
  }

  <<__Override>>
  public function getFixedNode(
    FunctionCallExpression $node,
  ): FunctionCallExpression {
    $params = vec($node->getArgumentListx()->getChildren());
    $expected = $params[0];
    $actual = $params[1];
    $message = Vec\drop($params, 2);

    $rec = $node->getReceiver();
    invariant(
      $rec instanceof MemberSelectionExpression,
      'receiver should be a member selection expression',
    );

    return $node
      ->withReceiver(
        $rec->withObject(
          new FunctionCallExpression(
            new NameToken(
              $rec->getObject()->getFirstTokenx()->getLeading(),
              Missing(),
              'expect',
            ),
            new LeftParenToken(Missing(), Missing()),
            new EditableList(vec[$actual]),
            new RightParenToken(Missing(), Missing()),
          ),
        )
          ->withName(new NameToken(Missing(), Missing(), 'toBeSame')),
      )
      ->withArgumentList(
        new EditableList(Vec\concat(vec[$expected], $message)),
      );
  }
}

[fredemmott]

Done in that PR