liveforeverx/shackle

High Performance Erlang Network Client Framework

shackle

High Performance Erlang Network Client Framework

Requirements

• Erlang 16.0 +

Features

• Backpressure via backlog (OOM protection)
• Fast pool implementation (random, round_robin)
• Multi-protocol support (TCP / UDP)
• Performance optimized
• Request pipelining

How-to

Implementing a client

-behavior(shackle_client).
-export([
    init/0,
    setup/2,
    handle_request/2,
    handle_data/2,
    terminate/1
]).

-record(state, {
    buffer =       <<>> :: binary(),
    request_counter = 0 :: non_neg_integer()
}).

-spec init() -> {ok, State :: term()}.

init() ->
     {ok, #state {}}.

-spec setup(Socket :: inet:socket(), State :: term()) ->
    {ok, State :: term()} |
    {error, Reason :: term(), State :: term()}.

setup(Socket, State) ->
    case gen_tcp:send(Socket, <<"INIT">>) of
        ok ->
            case gen_tcp:recv(Socket, 0) of
                {ok, <<"OK">>} ->
                    {ok, State};
                {error, Reason} ->
                    {error, Reason, State}
            end;
        {error, Reason} ->
            {error, Reason, State}
    end.

-spec handle_request(Request :: term(), State :: term()) ->
    {ok, RequestId :: external_request_id(), Data :: iodata(), State :: term()}.

handle_request({Operation, A, B}, #state {
        request_counter = RequestCounter
    } = State) ->

    RequestId = request_id(RequestCounter),
    Data = request(RequestId, Operation, A, B),

    {ok, RequestId, Data, State#state {
        request_counter = RequestCounter + 1
    }}.

-spec handle_data(Data :: binary(), State :: term()) ->
    {ok, [{RequestId :: external_request_id(), Reply :: term()}], State :: term()}.

handle_data(Data, #state {
        buffer = Buffer
    } = State) ->

    Data2 = <<Buffer/binary, Data/binary>>,
    {Replies, Buffer2} = parse_replies(Data2, []),

    {ok, Replies, State#state {
        buffer = Buffer2
    }}.

-spec terminate(State :: term()) -> ok.

terminate(_State) -> ok.

Starting client pool

shackle_pool:start(pool_name(), client(), client_options(), pool_options())

client_options()

Name	Type	Default	Description
ip	inet:ip_address() | inet:hostname()	"127.0.0.1"	server ip
port	inet:port_number()	undefined	server port
protocol	shackle_tcp | shackle_udp	shackle_tcp	server protocol
reconnect	boolean()	true	reconnect closed connections
reconnect_time_max	pos_integer() | infinity	120000	maximum reconnect time in milliseconds
reconnect_time_min	pos_integer()	1000	minimum reconnect time in milliseconds
socket_options	[gen_tcp:connect_option() | gen_udp:option()]	[]	options passed to the socket

pool_options()

Name	Type	Default	Description
backlog_size	pos_integer() | infinty	1024	maximum number of concurrent requests per connection
pool_size	pos_integer()	16	number of connections
pool_strategy	random | round_robin	round_robin	connection selection strategy

Calling / Casting client

1> shackle:call(pool_name, {get, <<"test">>}).
{ok, <<"bar">>}

2> {ok, ReqId} = shackle:cast(pool_name, {get, <<"foo">>}).
{ok, {anchor, anchor_client, #Ref<0.0.0.2407>}}

3> shackle:receive_response(ReqId).
{ok, <<"bar">>}

Tests

make dialyzer
make elvis
make eunit
make xref

Clients

Name	Description
anchor	Memcached Client
buoy	HTTP 1.1 Client (alpha)
flare	Kafka Producer (alpha)
marina	Cassandra CQL Client

License

The MIT License (MIT)

Copyright (c) 2015-2016 Louis-Philippe Gauthier

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.