zackelia/ghidra-dark

Dark theme installer for Ghidra

ghidra-dark's Issues

didn't modify the launch.bat

I had the issue where it didn't applied the theme so I ran ghidraDebug.bat and:

ERROR Error loading Look and Feel: java.lang.ClassNotFoundException: com.formdev.flatlaf.FlatDarkLaf  (DockingWindowsLookAndFeelUtils.java:135)
java.lang.ClassNotFoundException: com.formdev.flatlaf.FlatDarkLaf
        at java.net.URLClassLoader.findClass(URLClassLoader.java:433) ~[?:?]
        at java.lang.ClassLoader.loadClass(ClassLoader.java:586) ~[?:?]
        at java.lang.ClassLoader.loadClass(ClassLoader.java:519) ~[?:?]
        at java.lang.Class.forName0(Native Method) ~[?:?]
        at java.lang.Class.forName(Class.java:466) ~[?:?]
        at javax.swing.SwingUtilities.loadSystemClass(SwingUtilities.java:2035) ~[?:?]
        at javax.swing.UIManager.setLookAndFeel(UIManager.java:637) ~[?:?]
        at ghidra.docking.util.DockingWindowsLookAndFeelUtils.installLookAndFeelByName(DockingWindowsLookAndFeelUtils.java:161) ~[Docking.jar:?]
        at ghidra.docking.util.DockingWindowsLookAndFeelUtils.lambda$setLookAndFeel$0(DockingWindowsLookAndFeelUtils.java:126) ~[Docking.jar:?]
        at ghidra.util.Swing.lambda$runNow$2(Swing.java:227) ~[Utility.jar:?]
        at java.awt.event.InvocationEvent.dispatch(InvocationEvent.java:316) ~[?:?]
        at java.awt.EventQueue.dispatchEventImpl(EventQueue.java:770) ~[?:?]
        at java.awt.EventQueue$4.run(EventQueue.java:721) ~[?:?]
        at java.awt.EventQueue$4.run(EventQueue.java:715) ~[?:?]
        at java.security.AccessController.doPrivileged(AccessController.java:391) [?:?]
        at java.security.ProtectionDomain$JavaSecurityAccessImpl.doIntersectionPrivilege(ProtectionDomain.java:85) [?:?]
        at java.awt.EventQueue.dispatchEvent(EventQueue.java:740) [?:?]
        at java.awt.EventDispatchThread.pumpOneEventForFilters(EventDispatchThread.java:203) [?:?]
        at java.awt.EventDispatchThread.pumpEventsForFilter(EventDispatchThread.java:124) [?:?]
        at java.awt.EventDispatchThread.pumpEventsForHierarchy(EventDispatchThread.java:113) [?:?]
        at java.awt.EventDispatchThread.pumpEvents(EventDispatchThread.java:109) [?:?]
        at java.awt.EventDispatchThread.pumpEvents(EventDispatchThread.java:101) [?:?]
        at java.awt.EventDispatchThread.run(EventDispatchThread.java:90) [?:?]

however, I was able to get it working after modifying launch.bat to:

 @echo off
goto continue

:showUsage
echo Usage: %0 ^<mode^> ^<name^> ^<max-memory^> "<vmarg-list>" ^<app-classname^> ^<app-args^>... 
echo    ^<mode^>: fg    run as foreground process in current shell
echo              bg    run as background process in new shell
echo              debug run as foreground process in current shell in debug mode ^(suspend=n^)
echo              debug-suspend   run as foreground process in current shell in debug mode ^(suspend=y^)
echo              NOTE: for all debug modes environment variable DEBUG_ADDRESS may be set to 
echo                    override default debug address of 127.0.0.1:18001
echo    ^<name^>: application name used for naming console window
echo    ^<max-memory^>: maximum memory heap size in MB ^(e.g., 768M or 2G^).  Use "" if default should be used.
echo                  This will generally be upto 1/4 of the physical memory available to the OS.  On 
echo                  some systems the default could be much less (particularly for 32-bit OS).
echo    ^<vmarg-list^>: pass-thru args ^(e.g.,  "-Xmx512M -Dmyvar=1 -DanotherVar=2"^) - use
echo                empty "" if vmargs not needed
echo    ^<app-classname^>: application classname ^(e.g., ghidra.GhidraRun ^)
echo    ^<app-args^>...: arguments to be passed to the application
echo.
echo    Example: 
echo       %0 debug Ghidra 768M "" ghidra.GhidraRun
exit /B 1

:continue

:: See if we were doubled clicked or run from a command prompt
set DOUBLE_CLICKED=n
for /f "tokens=2" %%# in ("%cmdcmdline%") do if /i "%%#" equ "/c" set DOUBLE_CLICKED=y

:: Sets SUPPORT_DIR to the directory that contains this file (launch.bat).
:: SUPPORT_DIR will not contain a trailing slash.
::
:: '% ~' dereferences the value in param 0
:: 'd' - drive
:: 'p' - path (without filename)
:: '~0,-1' - removes trailing \
set "SUPPORT_DIR=%~dp0"
set "SUPPORT_DIR=%SUPPORT_DIR:~0,-1%"

:: Ensure Ghidra path doesn't contain illegal characters
if not "%SUPPORT_DIR:!=%"=="%SUPPORT_DIR%" (
	echo Ghidra path cannot contain a "!" character.
	set ERRORLEVEL=1
	goto exit1
)

:: Delay the expansion of our loop items below since the value is being updated as the loop works
setlocal enabledelayedexpansion

::
:: Parse arguments
::
set VMARG_LIST=
set ARGS=
set INDEX=0
for %%A in (%*) do (
	set /A INDEX=!INDEX!+1
	if "!INDEX!"=="1" ( set MODE=%%A
	) else if "!INDEX!"=="2" ( set APPNAME=%%A
	) else if "!INDEX!"=="3" ( set MAXMEM=%%~A
	) else if "!INDEX!"=="4" ( if not "%%~A"=="" set VMARG_LIST=%%~A
	) else if "!INDEX!"=="5" ( set CLASSNAME=%%~A
	) else set ARGS=!ARGS! %%A
)

if %INDEX% geq 5 goto continue1
echo Incorrect launch usage - missing argument^(s^)
goto showUsage

:continue1

::
:: Production Environment
::
set "INSTALL_DIR=%SUPPORT_DIR%\.."
set "CPATH=%INSTALL_DIR%\Ghidra\Framework\Utility\lib\Utility.jar;%INSTALL_DIR%\flatlaf-0.43.jar"
set "LS_CPATH=%SUPPORT_DIR%\LaunchSupport.jar"
set "DEBUG_LOG4J=%SUPPORT_DIR%\debug.log4j.xml"

if exist "%INSTALL_DIR%\Ghidra" goto continue2

::
:: Development Environment
::
set "INSTALL_DIR=%INSTALL_DIR%\..\..\.."
set "CPATH=%INSTALL_DIR%\Ghidra\Framework\Utility\bin\main;%INSTALL_DIR%\flatlaf-0.43.jar"
set "LS_CPATH=%INSTALL_DIR%\GhidraBuild\LaunchSupport\bin\main"
set "DEBUG_LOG4J=%INSTALL_DIR%\Ghidra\RuntimeScripts\Common\support\debug.log4j.xml"
if not exist "%LS_CPATH%" (
	echo Ghidra cannot launch in development mode because Eclipse has not compiled its class files.
	set ERRORLEVEL=1
	goto exit1
)

:continue2

:: This is to force Java to use the USERPROFILE directory for user.home
if exist "%USERPROFILE%" (
	set VMARG_LIST=%VMARG_LIST% -Duser.home="%USERPROFILE%"
)

:: Make sure some kind of java is on the path.  It's required to run the LaunchSupport program.
java -version >nul 2>nul
if not %ERRORLEVEL% == 0 (
	echo Java runtime not found.  Please refer to the Ghidra Installation Guide's Troubleshooting section.
	goto exit1
)

:: Get the JDK that will be used to launch Ghidra
set JAVA_HOME=
for /f "delims=*" %%i in ('java -cp "%LS_CPATH%" LaunchSupport "%INSTALL_DIR%" -jdk_home -save') do set JAVA_HOME=%%i
if "%JAVA_HOME%" == "" (
	:: No JDK has been setup yet.  Let the user choose one.
	java -cp "%LS_CPATH%" LaunchSupport "%INSTALL_DIR%" -jdk_home -ask
	
	:: Now that the user chose one, try again to get the JDK that will be used to launch Ghidra
	for /f "delims=*" %%i in ('java -cp "%LS_CPATH%" LaunchSupport "%INSTALL_DIR%" -jdk_home -save') do set JAVA_HOME=%%i
	if "!JAVA_HOME!" == "" (
		echo.
		echo Failed to find a supported JDK.  Please refer to the Ghidra Installation Guide's Troubleshooting section.
		set ERRORLEVEL=1
		goto exit1
	)
)
set "JAVA_CMD=%JAVA_HOME%\bin\java"

:: Get the configurable VM arguments from the launch properties
for /f "delims=*" %%i in ('java -cp "%LS_CPATH%" LaunchSupport "%INSTALL_DIR%" -vmargs') do set VMARG_LIST=%VMARG_LIST% %%i

:: Set Max Heap Size if specified
if not "%MAXMEM%"=="" (
	set VMARG_LIST=%VMARG_LIST% -Xmx%MAXMEM%
)

set BACKGROUND=n
set DEBUG=n
set SUSPEND=n

if "%MODE%"=="debug" (
	set DEBUG=y
)

if "%MODE%"=="debug-suspend" (
	set DEBUG=y
	set SUSPEND=y
)
	
if "%DEBUG%"=="y" (
	if "%DEBUG_ADDRESS%"=="" (
		set DEBUG_ADDRESS=127.0.0.1:18001
	)
		
	set VMARG_LIST=!VMARG_LIST! -Dlog4j.configuration="!DEBUG_LOG4J!"	
	set VMARG_LIST=!VMARG_LIST! -agentlib:jdwp=transport=dt_socket,server=y,suspend=!SUSPEND!,address=!DEBUG_ADDRESS!
	goto continue3
)

if "%MODE%"=="fg" (
	goto continue3
)

if "%MODE%"=="bg" (
	set BACKGROUND=y
	goto continue3
)

echo "Incorrect launch usage - invalid launch mode: %MODE%"
exit /B 1

:continue3

set CMD_ARGS=%FORCE_JAVA_VERSION% %JAVA_USER_HOME_DIR_OVERRIDE% %VMARG_LIST% -cp "%CPATH%" ghidra.GhidraLauncher %CLASSNAME% %ARGS%

if "%BACKGROUND%"=="y" (
	set JAVA_CMD=!JAVA_CMD!w
	start "%APPNAME%" /I /B "!JAVA_CMD!" %CMD_ARGS%
	
	REM If our process dies immediately, output something so the user knows to run in debug mode.
	REM Otherwise they'll never see any error output from background mode.
	REM NOTE: The below check isn't perfect because they might have other javaw's running, but
	REM without the PID of the thing we launched, it's the best we can do (maybe use WMI?).  
	REM Worst case, they just won't see the error message.
	%SystemRoot%\System32\timeout.exe /NOBREAK 1 > NUL
	%SystemRoot%\System32\tasklist.exe | %SystemRoot%\System32\findstr.exe "javaw" > NUL
	if not "!ERRORLEVEL!"=="0" (
		echo Exited with error.  Run in foreground ^(fg^) mode for more details.
	)
) else (
	"%JAVA_CMD%" %CMD_ARGS%
)

:exit1
if not %ERRORLEVEL% == 0 (
	if "%DOUBLE_CLICKED%"=="y" (
		pause
	)
)

exit /B %ERRORLEVEL%

the most important lines are:

::
:: Production Environment
::
set "INSTALL_DIR=%SUPPORT_DIR%\.."
set "CPATH=%INSTALL_DIR%\Ghidra\Framework\Utility\lib\Utility.jar;%INSTALL_DIR%\flatlaf-0.43.jar"
set "LS_CPATH=%SUPPORT_DIR%\LaunchSupport.jar"
set "DEBUG_LOG4J=%SUPPORT_DIR%\debug.log4j.xml"

if exist "%INSTALL_DIR%\Ghidra" goto continue2

::
:: Development Environment
::
set "INSTALL_DIR=%INSTALL_DIR%\..\..\.."
set "CPATH=%INSTALL_DIR%\Ghidra\Framework\Utility\bin\main;%INSTALL_DIR%\flatlaf-0.43.jar"
set "LS_CPATH=%INSTALL_DIR%\GhidraBuild\LaunchSupport\bin\main"
set "DEBUG_LOG4J=%INSTALL_DIR%\Ghidra\RuntimeScripts\Common\support\debug.log4j.xml"

after adding that the theme was applied so maybe I could help?

Some windows are missing dark theme

Hello,

There are small issues with theme (missing dark theme):

Window -> Bookmarks
Window -> Bytes
Window -> Bundle Manager
Window -> Comments
Window -> Data Type Manager
Window -> Defined Data
Window -> Defined Strings
Window -> Disassembled View
Window -> Functions
Window -> Memory Map
Window -> Relocation Table
Window -> Script Manager
Window -> Symbol References
Window -> Symbol Table

Graph -> Block Flow
Graph -> Code Flow
Graph -> Calls

Question about setting color in other views

Hello, thanks for the amazing project :)

However I've found that some of the views aren't quite fit into the FlatLaf's dark theme.

For example the function view:

Defined string view:

Script manager:

kind of hard to read the words in those views. Anyway we could fix this ?

Also I would like to know if there's a way to change the font color in python interpreter / console ? For now the font color is black and I would like to change that:

Unable to reset theme to default

Hello

After trying this theme (which can be great at night), I am unable to change the ghidra theme back to default white.
I tried deleting the ghidra folder and reinstalling it but the code browser and the decompiler are still dark :

Any help is appreciated.

Ghidra directory name in user's home directory

I was recently asked to help troubleshoot why this script was not working correctly. When I attempted to install this on my Manjaro VM, using Ghidra version 9.2.3, I found that the home/{user}/.ghidra/ no longer contained .ghidra_version_PUBLIC. It appears that they have changed it to .ghidra_version_DEV. Now, this could simply be the fact that I got it from the Arch repo instead of installing it manually, however, it appears the same is true when installing this on Kali using Ghidra version 9.1.

It was simple enough to resolve. I just needed to go to line 96 of install.py and change _PUBLIC to _DEV. However, it might be a good idea to add this in. Again, I do not know if this is version-dependent or if it is just certain installations. I can add some checks to the script to determine if the directory is _PUBLIC or _DEV with a pull request if you would like.

For now, anyone who runs into an issue with the script being unable to locate /home/user/.ghidra/.ghidra_{version}_PUBLIC/preferences, you will want to navigate to /home/user/.ghidra/ and make see if you have .ghidra_9.2.3_PUBLIC or .ghidra_9.2.3_DEV. If you have _DEV, you can resolve the issue by opening install.py and changing line 96 from _PUBLIC to _DEV.

Windows support

I'll start by saying that I managed to install this theme on Windows 10 (x64) just now.
It doesn't work straight away and there are 3 issues which I encountered that I've listed below.

Apologies for not submitting a pull request, I don't want to break the repo for other platforms and I can't test on Linux/macOS

Things to fix:

• Install.py:17: running pgrep obviously fails on windows. I even have cygwin installed with some default utilities and it doesn't exist. I was too lazy to figure out how to iterate processes so I just commented that code out and made sure ghidra was closed.

• Install.py:56: To enable FlatLaf on windows the file launch.bat should be updated instead of launch.sh.
  Within launch.bat It should turn these lines:

set CPATH=%INSTALL_DIR%Ghidra\Framework\Utility\lib\Utility.jar
set CPATH=%INSTALL_DIR%Ghidra\Framework\Utility\bin\main

to these:

set CPATH=%INSTALL_DIR%Ghidra\Framework\Utility\lib\Utility.jar;%INSTALL_DIR%flatlaf-0.43.jar
set CPATH=%INSTALL_DIR%Ghidra\Framework\Utility\bin\main;%INSTALL_DIR%flatlaf-0.43.jar

(The search and replace logic is similar to the one for launch.sh)

• tcd_browser.py:72: Something about iterating the 'STATE' elements just didn't work for me. Wrong elements were updated (colors for one element given to another) and I can't tell why would using Windows cause this. maybe it's an issue for all platforms?
  I fixed it by iterating the children of the current element instead of the entire category:
  Old code:

                            e = [_ for _ in category.iter() if _.get("NAME") == state.name][0]

New Code:

                            e = [_ for _ in element.iter() if _.get("NAME") == state.name][0]

Does not work with flatpak-installed Ghidra

I know it's far from standard, but with --path set to user's mount of Ghidra ("~/.var/app/org.ghidra_sre.Ghidra/") script fails to see files that it needs, with errors such as
FileNotFoundError: [Errno 2] No such file or directory: '/home/marcin/.var/app/org.ghidra_sre.Ghidra/Ghidra/application.properties'

application.properties can be found at ~/.var/app/org.ghidra_sre.Ghidra/config

macOS Brew Install issues

Hello having a similar looking issue to #19. I have Ghidra installed with Homebrew on macOS. Not sure where the application.properties file should be stored.

Traceback (most recent call last):
  File "/Users/Ethan/Developer/Tools/ghidra-dark/install.py", line 270, in <module>
    main(parser.parse_args())
  File "/Users/Ethan/Developer/Tools/ghidra-dark/install.py", line 240, in main
    ghidra_version = get_ghidra_version(ghidra_install_path)
  File "/Users/Ethan/Developer/Tools/ghidra-dark/install.py", line 96, in get_ghidra_version
    with open(properties_path, "r") as fp:
FileNotFoundError: [Errno 2] No such file or directory: '/usr/local/bin/Ghidra/application.properties'

Some parts are not set to dark mode

Several screens are displayed in light mode, with the characters still in the dark mode color pallet, making some text hard to read. This includes undefined functions, bookmarks tab, graph view, and more.

Comments color is unreadable

Hello,

Please, check the issue:

Comments are not so easy to read.

File permissions do not use --user flag

Hi there! So I installed and uninstalled this by using specifying my user with the --user flag, however because I was running the installer with sudo the files created in the .ghidra/.ghidra_10.1.1_DEV/tools/ directory are owned by root, rather than the specified user. This means I get an error on launch of Ghidra.

Cannot find: ~/.ghidra/.ghidra_10.1.1_DEV/tools/_code_browser.tcd

This includes everything from ./tools/ and the ./permissions file. It's an easy fix on my part just to add permissions to these files. It's odd though that it only effected me when uninstalling.

I believe this may be because it takes a backup of the files to then restore, but that restore process uses the wrong permissions. This issue occurs on further installs/uninstalls. So I assume at some point these files lose their user permissions.

Installing to system Ghidra in Arch Linux needs workaround

Hi,

either it's not working out of the box with system wide Ghidra in Arch Linux or I simply don't understand the install process. It's unable to find Ghidra installation and when pointed to /opt/ghidra/ it complains with ERROR: Please open Ghidra at least once to fully install dark mode.

Best

Problem with Ubuntu Linux when run as root

So my ghidra is in my root and my .ghidra file is in my home dir. It gave error because it detect home path as /root/.ghidra/... But real path is /home/username/.ghidra. I fixed It by changing getHome path code to "/home/username" but It failed on my first run. So maybe there can be question for where is your .ghidra path to user if try to get from home path failes?

-Sorry for my bad English.-

java.lang.Error: no ComponentUI class for: docking.DialogComponentProvider

this breaks with

• ghidra-10.2.2
• flatlaf-3.0.jar from maven

ghidra fails to start and deadloops with these errors

java.lang.Error: no ComponentUI class for: docking.DialogComponentProvider$1
java.lang.Error: no ComponentUI class for: docking.ErrLogDialog$1
java.lang.Error: no ComponentUI class for: docking.ErrLogDialog$ErrorDetailsPanel
java.lang.Error: no ComponentUI class for: docking.ErrLogDialog$ErrorDetailsSplitPane
java.lang.Error: no ComponentUI class for: docking.widgets.label.GDHtmlLabel
java.lang.Error: no ComponentUI class for: docking.widgets.label.GIconLabel
java.lang.Error: no ComponentUI class for: docking.widgets.label.GLabel
java.lang.Error: no ComponentUI class for: docking.widgets.ScrollableTextArea$PrivateTextArea
java.lang.Error: no ComponentUI class for: docking.widgets.ScrollableTextArea
java.lang.Error: no ComponentUI class for: javax.swing.JButton
java.lang.Error: no ComponentUI class for: javax.swing.JMenuItem
java.lang.Error: no ComponentUI class for: javax.swing.JPanel
java.lang.Error: no ComponentUI class for: javax.swing.JPopupMenu
java.lang.Error: no ComponentUI class for: javax.swing.JRootPane
java.lang.Error: no ComponentUI class for: javax.swing.JScrollPane$ScrollBar
java.lang.Error: no ComponentUI class for: javax.swing.JViewport

related

https://stackoverflow.com/questions/64693776/strange-problem-with-java-flatlaf-java-lang-error-no-componentui-class-for-jl

JFormDesigner/FlatLaf#104

maybe this is obsolete since ghidra 2022-11-15
NationalSecurityAgency/ghidra#4145 (comment)

kali 2021 issue

Sounds good your dark theme , below some issues with default kali 2021

$ python3 install.py --path /usr/share/ghidra 
[../snip]
PermissionError: [Errno 13] Permission denied: '/usr/share/ghidra/flatlaf-0.43.jar'
                                                                                                                                                      
$ sudo python3 install.py --path /usr/share/ghidra 
[sudo] password for test: 
ERROR: Please open Ghidra at least once to fully install dark mode.
                                                                                                                                                      
``
After that I restarted my ghidra but was not applied theme...

Some GUI elements are rendered unreadably

This seems potentially related to #27, but it doesn't exactly look the same and the severity is quite a bit worse. I see the color theme applied to almost all areas I care about, but certain areas become unusable, for example the strings tab, the script manager, the keybinding configuration dialog. The text in these areas is rendered as slighly off-white against a white background. I suspect that this is an issue due to the general dark OS theme... I don't know, I'm out of my depth on this one.

OS: Pop_OS 21.10
Ghidra: 10.1.2
ghidra-dark: ab7ca33

Ghidra >=10.3 support

This project no longer works with the upcoming 10.3 release because there is now a proper theming feature! While it does come with a dark theme, if you want to maintain a similar feel to ghidra-dark, check out my ghidra-dark-theme repo.

get_ghidra_config_path version number bug

The following lines check each mapped number in the tuple individually, no? So the check will fail if any of the numbers are less than the mapped number even if the total version number is higher?

74    if tuple(map(int, (version_number.split(".")))) > (9, 0, 4):
75        version_path = f".ghidra_{version}_PUBLIC"

I am running version 10.0.2 and the installation is failing because 2 > 4.

The install is failing because it can't find my $HOME/.ghidra/.ghidra directory because it's looking for a $HOME/.ghidra/.ghidra-{version}_PUBLIC instead of $HOME/.ghidra/.ghidra_{version}_PUBLIC.

custom Ghidra home path

I am using the AUR version of ghidra, so the ghidra path is /opt/ghidra, so the installer has to be ran as root (or sudo).

The script takes the home path via Path.home() (line 99) which is /root while it should be /home/myUserName

Edit: A hacky way to get it to install (in case you have the same problem) would be to hardcode the path in line 99 ghidra_home_path = os.path.join("/home/myUserName", ".ghidra", version_path)

theme doesn't apply globally (looks weird)

That's what i am talking

Uninstallation

I'm having trouble getting rid of the effects, can you please make an uninstall script?

How to get Ghidra to look like the screenshot

I have ran the script, and it has changed the colors of the disassembly/assembler but the actual GUI still looks half-white for the menu's and what not. I am on Windows and don't know if that matters, I tried the inverted colors, but it makes everything black instead of the nice grey that the screenshot is like. I'm not sure if this is just a Windows bug, or what. By default I was on System with Inverted Colors unchecked, but don't know which Theme/Inverted colors options are supposed to be selected.

Not really an issue, more of an general question :)

How to convert color between rgb format and ghidra format?

I want to customize some color in "preferences.py", but i have no idea how to convert rgb color to the negative color format in "preferences.py", pls help

URL hard coded is not reachable

The URL https://bintray.com/jformdesigner/flatlaf/download_file?file_path=com/formdev/flatlaf/0.4 is returning a forbidden.

Cannot install the theme while this is the issue.

9.2.1 Decompiler background still white

Not sure if I did something wrong, just trying this for the first time. Fresh install of Ghidra 9.2.1 and ghidra-dark. Menus, buttons, scroll bars and project manager are dark. But Decompiler code browser is still bright.

Cant get it to work ::CCC

PS C:\Users\mmat0\Desktop\ghidra-dark-main> python install.py --path 'C:\Program Files\GhidraDecompiler'
Traceback (most recent call last):
File "C:\Users\mmat0\Desktop\ghidra-dark-main\install.py", line 270, in
main(parser.parse_args())
File "C:\Users\mmat0\Desktop\ghidra-dark-main\install.py", line 240, in main
ghidra_version = get_ghidra_version(ghidra_install_path)
File "C:\Users\mmat0\Desktop\ghidra-dark-main\install.py", line 96, in get_ghidra_version
with open(properties_path, "r") as fp:
OSError: [Errno 22] Invalid argument: 'C:\Program Files\GhidraDecompiler"\Ghidra\application.properties'

Idk how to get it to work

Doesn't work with 10-Beta due to having string in int()

Version tracking

Everything works as expected except when using version tracking, which remains the default theme. Can you update this to where version tracking also is dark theme?